论坛 › ＰＣ数码 › 求一个只带定时关机功能的软件

雁过留痕 发表于 2015-4-7 13:33

求一个只带定时关机功能的软件

不要其它功能
WIN系统(不想用附件自带程序管理工能）
只求简单方便

hftrrt 发表于 2015-4-7 13:36

千宇智能关机

zs1109 发表于 2015-4-7 13:37

shutdown /s /t 3600 (3600是秒数，做一个bat就是

ostcollector 发表于 2015-4-7 14:04

计划任务

museqsou 发表于 2015-4-7 22:19

shutdown -s -f -t time(mile second)

一炮交友 发表于 2015-4-7 23:32

shutdown -s -t 1112312412

粉有 发表于 2015-4-8 02:19

迅雷 添加计划任务 关机

superchenxx 发表于 2015-4-8 13:46

用计划任务吧
at time shutdown /s
time换成指定的时间就好了

gaowe 发表于 2015-4-8 13:50

写个bat，双击一下又快又好，又不用怕沾上流氓

----发送自 HUAWEI HUAWEI G750-T01,Android 4.2.2

real_zyf 发表于 2015-4-8 13:53

pk1308 发表于 2015-4-8 15:39

千千静听自带

andm 发表于 2015-4-8 16:03

本帖最后由 andm 于 2015-4-8 16:06 编辑

转一个网上的定时关机的脚本，复制代码到记事本，再另存.bat就好。
我电脑就是在用这个。代码非本人所编，如用得上请自行审计代码。
代码如下 ：@Echo off
TITLE 定时关机

:start
CLS
COLOR 0a
rem COLOR命令更改控制台颜色,0-f可控制前背景
MODE con: COLS=40 LINES=20
rem MODE命令设定窗体的宽和高
set tm1=%time:~0,2%
set tm2=%time:~3,2%
set tm3=%time:~6,2%
ECHO %date% %tm1%点%tm2%分%tm3%秒
ECHO ========================================
ECHO         请键入操作序号,回车键确认
ECHO    ─────────────────
ECHO.
ECHO    1. 】定点关机【   A. 】设置广播【
ECHO    2. 】计时关机【   B. 】开启广播【
ECHO    3. 】任务状态【   C. 】关闭广播【
ECHO    4. 】删除任务【   D. 】广播状态【
ECHO    5. 】创建语音【   E. 】强制删除【
ECHO    6. 】清除垃圾【   F. 】重新启动【
ECHO    7. 】定点闹钟【   G. 】锁定电脑【
ECHO    8. 】闹钟状态【   H. 】注销登陆【
ECHO    9. 】删除闹钟【   I. 】退出程序【
ECHO.
ECHO ========================================
ECHO.

:cho
SET Choice=
SET /P Choice=选择:
rem 设定变量"Choice"为用户输入的字符
IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1%
rem 如果输入大于1位,取第1位,比如输入132,则返回值为1
ECHO.
IF /I "%Choice%"=="1" GOTO SetHour
IF /I "%Choice%"=="2" GOTO how
IF /I "%Choice%"=="3" GOTO view
IF /I "%Choice%"=="4" GOTO delAt
IF /I "%Choice%"=="5" GOTO speaker
IF /I "%Choice%"=="6" GOTO clean
IF /I "%Choice%"=="7" GOTO SetAlarm
IF /I "%Choice%"=="8" GOTO AlarmState
IF /I "%Choice%"=="9" GOTO del8t
rem
IF /I "%Choice%"=="a" GOTO ShareWlan
IF /I "%Choice%"=="b" GOTO Wlanon
IF /I "%Choice%"=="c" GOTO Wlanoff
IF /I "%Choice%"=="d" GOTO show
IF /I "%Choice%"=="e" GOTO del
IF /I "%Choice%"=="f" GOTO restart
IF /I "%Choice%"=="g" GOTO lock
IF /I "%Choice%"=="h" GOTO logoff
IF /I "%Choice%"=="i" GOTO end
rem
rem 为避免出现返回值为空或含空格而导致程序异常,需在变量外另加双引号
rem 注意,IF语句需要双等于号
rem 如果输入的字符不是以上数字,将返回重新输入
ECHO 选择无效，请重新输入
ECHO.
GOTO cho

:SetHour
CLS
ECHO.
ECHO.
ECHO    **********************************
ECHO      定时关机: 请选择定时模式
ECHO.
ECHO          # 一次任务(直接回车)
ECHO.
ECHO          # 日常任务(空格回车)
ECHO.
ECHO    **********************************
ECHO.
ECHO.
SET ask=
SET /p ask= 》   》》》》》请选择模式《《《《《   《
IF NOT "%ask%"=="" SET ask=%ask:~0,1%
IF /I "%ask%"=="" GOTO once
IF /I "%ask%"==" " GOTO daily
GOTO SetHour

:once
ECHO 请指定24小时制式时间,格式为 小时:分钟
ECHO例如:00:00或19:30 [模式:ONCE]
ECHO ========================================
SET shutdowntime=
SET /p shutdowntime=定时:
SCHTASKS /Create /SC ONCE /TN 定时关机 /TR "shutdown.exe -s -hybrid -t 10" -st "%shutdowntime%" /f
IF NOT errorlevel 1 GOTO ok
ECHO %shutdowntime% 不是标准的时间格式,请重新输入
ECHO.
GOTO once

:daily
ECHO 请指定24小时制式时间,格式为 小时:分钟
ECHO例如:00:00或19:30 [模式:DAILY]
ECHO ========================================
SET shutdowntime=
SET /p shutdowntime=定时:
SCHTASKS /Create /SC DAILY /TN 定时关机 /TR "shutdown.exe -s -hybrid -t 10" -st "%shutdowntime%" /f
rem 设定为Daily任务,将在每天执行.
IF NOT errorlevel 1 GOTO ok
rem 如果输入正确,就执行ok段的语句
ECHO %shutdowntime% 不是标准的时间格式,请重新输入
ECHO.
GOTO daily

:ok
ECHO.
SET h=%shutdowntime:~1,1%
SET ah=%shutdowntime:~0,1%
SET am=%shutdowntime:~2,2%
SET bh=%shutdowntime:~0,2%
SET bm=%shutdowntime:~3,2%
IF "%h%"==":" (
SET HM=%ah%时%am%分
) ELSE (
SET HM=%bh%时%bm%分)
rem 如果输入h:mm则HM=h时mm分,否则HM=hh时mm分
IF /I "%ask%"==" " ECHO 系统将于每天的%HM%关闭
IF /I "%ask%"=="" ECHO 系统将于随后的%HM%关闭
ECHO +++++++++++++++++++++++++++++++
ECHO 设定完毕! 按任意键继续...
PAUSE >nul
GOTO start

:how
CLS
ECHO.
ECHO.
ECHO    **********************************
ECHO       倒计时关机: 请选择计时模式
ECHO.
ECHO          # 内置计时(直接回车)
ECHO.
ECHO          # 系统计时(空格回车)
ECHO.
ECHO    **********************************
ECHO.
SET ask=
SET /p ask= 》   》》》》》请选择模式《《《《《   《
IF /I "%ask%"=="" GOTO countdown
IF /I "%ask%"==" " GOTO outtime
IF /I "%ask%"=="exit" GOTO star
GOTO how

:outtime
rem CLS
ECHO.
ECHO 当前时间:%tm1%点%tm2%分%tm3%秒
ECHO ────────———————————
ECHO 请输入倒计时秒数(shutdown计时模式)
SET timed=
SET /p timed=输入:
shutdown.exe -s -hybrid -t %timed%
IF not errorlevel 1 GOTO continue
ECHO.
ECHO       ++++++++++++++++++++++++++++
ECHO         输入错误,或已存在关机计划
ECHO       ++++++++++++++++++++++++++++
ECHO.
GOTO error

:error
ECHO      ENTER返回 2SPACE+ENTER清除
ECHO.
SET /p ask= 》   》》》》》请选择操作《《《《《   《
IF /I "%ask%"==" " GOTO start
IF /I "%ask%"=="" GOTO cancel
ECHO.


:continue
rem cls
ECHO 系统将于%timed%s后关闭
ECHO.
ECHO 》   》》》》》请选择操作《《《《《   《
ECHO      ENTER返回 2SPACE+ENTER清除
ECHO.
SET /p ask= 》   》》》》》请选择操作《《《《《   《
IF /I "%ask%"==" " GOTO start
IF /I "%ask%"=="" GOTO cancel


:countdown
@echo off & setlocal enableextensions
echo WScript.Sleep 1000 > %temp%\tmp$.vbs
ECHO.
ECHO 当前时间:%tm1%点%tm2%分%tm3%秒
ECHO ────────———————————
ECHO 请输入倒计时秒数(计时shutdown模式)
SET timed=
SET /p timed=输入:
set /a i = %timed%
:Timeout
MODE con: COLS=38 LINES=10
if %i% == 0 goto Next
setlocal
set /a i = %i% - 1
cls
echo            倒计时关机程式
echo.
echo.
echo###################################
echo   #                               #
echo       [%i%]秒后关闭您的计算机         
echo   #                               #
echo###################################
cscript //nologo %temp%\tmp$.vbs
goto Timeout
goto End

:Next
cls & echo.
shutdown.exe -s -hybrid -t 0
for %%f in (%temp%\tmp$.vbs) do del %%f
exit

:delAt
rem cls
echo    将删除您的定时关机任务
ECHO +++++++++++++++++++++++++++++++
SCHTASKS /Delete /TN 定时关机
pause >nul
GOTO start

:view
MODE con: COLS=80 LINES=18
COLOR 0a
ECHO.
ECHO 当前时刻:%date%%tm1%点%tm2%分%tm3%秒
ECHO.
ECHO ++++++》》》》》》》》》》》》》》》任务信息《《《《《《《《《《《《《《《++++++
ECHO.
schtasks /query /TN 定时关机
ECHO.
ECHO.%errorlevel%
ECHO ++++++》》》》》》》》》》》》》》》任务信息《《《《《《《《《《《《《《《++++++
ECHO.
ECHO.
ECHO 按任意键返回...
PAUSE >nul
GOTO start

:cancel
shutdown -a
ECHO 已取消关机计划 5秒后返回...
for %%z in (》 ) do (
for /l %%i in (20 -1 1) do (
for /l %%j in (1 1 %%i) do (set/p= <nul)
   set/p=%%z<nul
   set/p= <nul
for /l %%k in (1 1 1000) do (set/p=<nul)
)
)
GOTO start

rem闹钟

:SetAlarm
CLS
ECHO.
ECHO.
ECHO    **********************************
ECHO      定点闹钟: 请选择定时模式
ECHO.
ECHO          # 一次任务(直接回车)
ECHO.
ECHO          # 日常任务(空格回车)
ECHO.
ECHO    **********************************
ECHO.
ECHO.
SET ask=
SET /p ask= 》   》》》》》请选择模式《《《《《   《
IF NOT "%ask%"=="" SET ask=%ask:~0,1%
IF /I "%ask%"=="" GOTO oncealarm
IF /I "%ask%"==" " GOTO dailyalarm
GOTO SetAlarm


:oncealarm
ECHO 请指定24小时制式时间,格式为 小时:分钟
ECHO例如:00:00或19:30 [模式:ONCE]
ECHO ========================================
SET alarmtime=
SET /p alarmtime=定时:
SET music=
cls
echo          请拖拽音乐文件到窗口
ECHO ========================================
echo 可指定广义闹钟，该闹钟可以是任何已知类
ECHO.
ECHO 如需添加参数，请拖入窗口后编辑引号内容
ECHO ========================================
SET /p music=%*
ECHO ========================================
SET hou=%alarmtime:~0,2%
SET min=%alarmtime:~3,2%
SET sec=%alarmtime:~6,2%
SET d8=0
SET lag=30
echo *请指定闹钟维持时间，默认延迟30分钟。
ECHO.
echo *维持时间必须大于10分钟，即播放周期。
ECHO.
echo *每个周期内闹钟将会播放一次，请留意。
SET /P lag=:
SET /a min+=%lag%
:min
If not %min% lss 60 (set /a min-=60 & set /a hou+=1 & goto hou) else (goto prt)
:hou
If not %hou% lss 24 (set /a hou-=24 & goto prt) else (goto prt)
:prt
echo 闹钟将在: %alarmtime:~0,2%时%alarmtime:~3,2%分开始
echo   并于: %hou%时%min%分%结束,请核对.
SET endtim=%hou%:%min%:00
SCHTASKS /Create /SC ONCE /TN 定点闹钟 /TR %music% /st %alarmtime% /et %endtim% /f
IF NOT errorlevel 1 GOTO ready
ECHO %alarmtime% 不是标准的时间格式,请重新输入
echo 或所指定闹钟文件路径存在问题
ECHO.
GOTO oncealarm

:dailyalarm
ECHO 请指定24小时制式时间,格式为 小时:分钟
ECHO例如:00:00或19:30 [模式:DAILY]
ECHO ========================================
SET alarmtime=
SET /p alarmtime=定时:
SET music=
cls
echo          请拖拽音乐文件到窗口
ECHO ========================================
echo 可指定广义闹钟，该闹钟可以是任何已知类
ECHO.
ECHO 如需添加参数，请拖入窗口后编辑引号内容
ECHO ========================================
SET /p music=%*
ECHO ========================================
SET hou=%alarmtime:~0,2%
SET min=%alarmtime:~3,2%
SET sec=%alarmtime:~6,2%
SET d8=0
SET lag=30
echo *请指定闹钟维持时间，默认延迟30分钟。
ECHO.
echo *维持时间必须大于10分钟，即播放周期。
ECHO.
echo *每个周期内闹钟将会播放一次，请留意。
SET /P lag=:
SET /a min+=%lag%
:min
If not %min% lss 60 (set /a min-=60 & set /a hou+=1 & goto hou) else (goto prt)
:hou
If not %hou% lss 24 (set /a hou-=24 & goto prt) else (goto prt)
:prt
echo 闹钟将在: %alarmtime:~0,2%时%alarmtime:~3,2%分开始
echo   并于: %hou%时%min%分%结束,请核对.
SET endtim=%hou%:%min%:00
SCHTASKS /Create /SC DAILY /TN 定点闹钟 /TR %music% /st %alarmtime% /et %endtim% /k /f
rem 设定为Daily任务,将在每天执行.
IF NOT errorlevel 1 GOTO ready
ECHO %alarmtime% 不是标准的时间格式,请重新输入
echo 或所指定闹钟文件路径存在问题
ECHO.
GOTO dailyalarm

:ready
ECHO.
SET h=%alarmtime:~1,1%
SET ah=%alarmtime:~0,1%
SET am=%alarmtime:~2,2%
SET bh=%alarmtime:~0,2%
SET bm=%alarmtime:~3,2%
IF "%h%"==":" (
SET HM=%ah%时%am%分
) ELSE (
SET HM=%bh%时%bm%分)
rem 如果输入h:mm则HM=h时mm分,否则HM=hh时mm分
IF /I "%ask%"==" " ECHO 系统将于每天的%HM%播放闹钟
IF /I "%ask%"=="" ECHO 系统将于随后的%HM%播放闹钟
ECHO +++++++++++++++++++++++++++++++
ECHO*设定完毕。按任意键返回...
PAUSE >nul
GOTO start

:AlarmState
MODE con: COLS=80 LINES=18
COLOR 0a
ECHO.
ECHO.
ECHO 当前时刻:%date%%tm1%点%tm2%分%tm3%秒
ECHO ++++++》》》》》》》》》》》》》》》任务信息《《《《《《《《《《《《《《《++++++
ECHO.
schtasks /query /TN 定点闹钟
ECHO.
ECHO.
ECHO ++++++》》》》》》》》》》》》》》》任务信息《《《《《《《《《《《《《《《++++++
ECHO.
ECHO.
ECHO 按任意键返回...
PAUSE >nul
GOTO start

:del8t
rem cls
echo    将删除您的定时闹钟任务
ECHO +++++++++++++++++++++++++++++++
SCHTASKS /Delete /TN 定点闹钟
ECHO 已取消闹钟计划 5秒后返回...
echo set ws = createobject("wscript.shell")>sleep5.vbs
echo WScript.Sleep 5000>>sleep5.vbs
sleep5.vbs
del sleep5.vbs
GOTO start
pause >nul
GOTO start

rem 热点 启动Adapter


:ShareWlan
CLS
ECHO.
ECHO    **********************************
ECHO       Adapter助手: 请选择您的操作
ECHO.
ECHO          # 创建热点(直接回车)
ECHO.
ECHO          # 删除热点(空格回车)
ECHO.
ECHO    **********************************
ECHO.
SET ask=
SET /p ask= 》   》》》》》请选择模式《《《《《   《
IF NOT "%ask%"=="" SET ask=%ask:~0,1%
IF /I "%ask%"=="" GOTO allow
IF /I "%ask%"==" " GOTO disallow
GOTO ShareWlan

:allow
SET ssid=
SET /p ssid=请输入广播地址ssid:
SET key=
SET /p key=请输入安全密码Key:
netsh wlan set hostednetwork mode=allow
netsh wlan set hostednetwork ssid=%ssid% key=%key% keyUsage=persistent
for %%z in (》 ) do (
for /l %%i in (20 -1 1) do (
for /l %%j in (1 1 %%i) do (set/p= <nul)
   set/p=%%z<nul
   set/p= <nul
for /l %%k in (1 1 1000) do (set/p=<nul)
)
)
GOTO start

:disallow
netsh wlan set hostednetwork mode=disallow
for %%z in (》 ) do (
for /l %%i in (20 -1 1) do (
for /l %%j in (1 1 %%i) do (set/p= <nul)
   set/p=%%z<nul
   set/p= <nul
for /l %%k in (1 1 1000) do (set/p=<nul)
)
)
rem pause>nul
goto start


:Wlanon
netsh wlan start hostednetwork
ECHO +++++++++++++++++++++++++++++++
ECHO*设定完毕。 按任意键返回...
PAUSE >nul
GOTO start

:Wlanoff
netsh wlan stop hostednetwork
ECHO +++++++++++++++++++++++++++++++
ECHO*设定完毕。 按任意键返回...
PAUSE >nul
GOTO start

:show
CLS
netsh wlan show hostednetwork
PAUSE >nul
GOTO start


rem 工具


:speaker
SET /p titl=请键入讲述人标题:
cls
echo windows讲述人：%titl%
ECHO +++++++++++++++++++++++++++++++
echo 正文
SET /p word=
ECHO +++++++++++++++++++++++++++++++
rem echo createobject("sapi.spvoice").speak("傻瓜，逗号，懂吗？")>%titl%.vbs
echo createobject("sapi.spvoice").speak("%word%")>%titl%.vbs
%titl%.vbs
echo 任意键将删除"%titl%"并返回
pause>nul
del /f /q %titl%.vbs
ECHO +++++++++++++++++++++++++++++++
echo 已删除讲述人"%titl%" 返回中..
for %%z in (》 ) do (
for /l %%i in (20 -1 1) do (
for /l %%j in (1 1 %%i) do (set/p= <nul)
   set/p=%%z<nul
   set/p= <nul
for /l %%k in (1 1 1000) do (set/p=<nul)
)
)
echo.&echo.&echo.
goto start


rem 系统

:del
cls
echo          请拖文件或文件夹到窗口
ECHO ========================================
echo.
echo       请不要以管理员身份运行此命令
echo.
SET g8=
SET /p g8=%*
DEL /F /A /Q \\?\%g8%
RD /S /Q \\?\%g8%
echo 删除完成
ECHO ========================================
for %%z in (》 ) do (
for /l %%i in (20 -1 1) do (
for /l %%j in (1 1 %%i) do (set/p= <nul)
   set/p=%%z<nul
   set/p= <nul
for /l %%k in (1 1 1000) do (set/p=<nul)
)
)
goto start

:clean
cls
@echo off

echo 正在清除系统垃圾文件，请稍等......
ECHO ========================================

del /f /s /q %systemdrive%\*.tmp

del /f /s /q %systemdrive%\*._mp

del /f /s /q %systemdrive%\*.log

del /f /s /q %systemdrive%\*.gid

del /f /s /q %systemdrive%\*.chk

del /f /s /q %systemdrive%\*.old

del /f /s /q %windir%\*.bak

rem del /f /s /q %windir%\prefetch\*.*
rem 预读

rd /s /q %windir%\temp & md %windir%\temp

del /f /q %userprofile%\recent\*.*

rem del /f /s /q "%userprofile%\Local Settings\Temporary Internet Files\*.*"
rd /s /q "%userprofile%\Local Settings\Temporary Internet Files"

del /f /s /q "%userprofile%\Local Settings\Temp\*.*"

del /f /s /q "%userprofile%\recent\*.*"

ECHO.
ECHO      是否清空C、D、E、F盘回收站
ECHO ========================================
ECHO      ENTER结束 2SPACE+ENTER清除
ECHO.
SET /p ask= 》   》》》》》请选择操作《《《《《   《
IF /I "%ask%"==" " GOTO clean2
IF /I "%ask%"=="" GOTO clean1
ECHO.
:clean1
del /f /s /q c:\$Recycle.Bin\*.*
del /f /s /q d:\$Recycle.Bin\*.*
del /f /s /q e:\$Recycle.Bin\*.*
del /f /s /q f:\$Recycle.Bin\*.*
rem 上行清空回收站
goto clean2

:clean2
ECHO ========================================

echo 清除系统垃圾完成。

for %%z in (》 ) do (
for /l %%i in (20 -1 1) do (
for /l %%j in (1 1 %%i) do (set/p= <nul)
   set/p=%%z<nul
   set/p= <nul
for /l %%k in (1 1 1000) do (set/p=<nul)
)
)
echo.&echo.&echo.
goto start


:restart
shutdown -r -t 0
goto end

:lock
rundll32.exe user32.dll,LockWorkStation
goto start

:logoff
logoff

:end
exit（上一行代码结束）

zerocount 发表于 2015-4-8 16:12

12l这简直丧心病狂。。。

nemo_mxc 发表于 2015-4-8 16:21

andm 发表于 2015-4-8 16:03
转一个网上的定时关机的脚本，复制代码到记事本，再另存.bat就好。
我电脑就是在用这个。代码非本人所编， ...

好东西。。。

查看完整版本: 求一个只带定时关机功能的软件